# RESERIES.CSM  Version 2.0.0000

name "Resolution Series Script"

# location in the menu
mode 0
menu "Kodak Scripts"
label "Resolution Series"

declare u:metr, uSsiz, uScpn, uCameraType, uImageTaken, uImageAvail, uStorage
declare u:uWena, uWsbc, uWsfc, uWsop, uWsxp, uWsyp, uCount, uIndex, uLength
declare u:uMenu, uActc, uBttc, uError
declare i:iImageRaw, iCount, iMcount
declare s:sGName, sProductName, sPath, sWstr
declare n:nName
declare b:bStatus, bsystat, bcamstat, bvendstat, bMask

#Initialize Master Count Variable
iMcount = 0

#Initialize System Status bit mask
bMask = 0x10000000

# group name - also the album/folder name
sGName = "RESERIES"

# Get camera type and use a unsigned integer to identify it
GetProductInfo ("ptid", sProductName)
if sProductName == "KODAK DIGITAL SCIENCE DC220"
	uCameraType = 220
end
if sProductName == "KODAK DIGITAL SCIENCE DC260"
	uCameraType = 260
end

if sProductName == "KODAK DC265 ZOOM DIGITAL CAMERA"
	uCameraType = 265
end

if sProductName == "KODAK DC290 Zoom Digital Camera"
	uCameraType = 290
end

# Error trap - in case of a product name change or being used
#	       on cameras other than DC220/DC260/DC265/DC290
if uCameraType != 220
	if uCameraType != 260
		if uCameraType != 265
			if uCameraType != 290		
				DisplayClear()
				DisplayLine("")
				DisplayLine("This script has to be used on Kodak DC220, DC260, DC265 or DC290 cameras only.")
				Wait(4000)
				goto Done
			end
		end
	end
end

# Set group capture
SetCaptureMode (group)

# get number of high/medium, better quality pictures available in the camera
# and use that to make a judgement over available memory

# picture size
GetCameraState ("ssiz", uSsiz)
# picture quality
GetCameraState ("scpn", uScpn)
if uCameraType == 220
	SetCameraState("ssiz", 1)
end
if uCameraType == 260
	SetCameraState("ssiz", 2)
end

if uCameraType == 265
	SetCameraState("ssiz", 2)
end

if uCameraType != 290
	SetCameraState ("scpn", 3)
end

# for DC290 use High/Uncompressed quality
if uCameraType == 290
	SetCameraState("ssiz", 1)
	SetCameraState ("scpn", 7)
end

# Check available memory
uStorage = 1
iImageRaw = -1
GetStorageStatus (uStorage, uImageTaken, uImageAvail, iImageRaw)
SetCameraState ("ssiz", uSsiz)
SetCameraState ("scpn", uScpn)
# use estimated memory space of 10/20 (about 2Mb/4MB) pictures at medium res/medium
# quality to measure space needed for the process
# DC290 needs about 5 (about 16Mb)  for testing

if uCameraType == 220
	if uImageAvail < 10
		DisplayClear()
		DisplayLine("Not enough memory to complete this operation.")
		DisplayLine("Please delete some images and try again.")
		Wait(5000)
		goto Done
	end
end
if uCameraType == 260
	if uImageAvail < 20
		DisplayClear()
		DisplayLine("Not enough memory to complete this operation.")
		DisplayLine("Please delete some images and try again.")
		Wait(5000)
		goto Done
	end
end

if uCameraType == 265
	if uImageAvail < 20
		DisplayClear()
		DisplayLine("Not enough memory to complete this operation.")
		DisplayLine("Please delete some images and try again.")
		Wait(5000)
		goto Done
	end
end

if uCameraType == 290
	if uImageAvail < 2
		DisplayClear()
		DisplayLine("Not enough memory to complete this operation.")
		DisplayLine("Please delete some images and try again.")
		Wait(5000)
		goto Done
	end
end

# Get file count from the camera
GetFileCount(uCount)
if uCount == 0
	goto ContinueScript
end

# loop through all pictures if see if there are any pictures in
# RESERIES album.  Note that two pathes are checked in case
# that the card has been used on a different camera
uIndex = 0
FileChkLoop:
	GetFileInfo(uIndex, sPath, nName, uLength, bStatus)
	if uCameraType == 220
		if sPath == "DC220_01/RESERIES/"
			goto OutFileChkLoop
		end
		if sPath == "DC220_02/RESERIES/"
			goto OutFileChkLoop
		end
	end
	if uCameraType == 260
		if sPath == "DC260_01/RESERIES/"
			goto OutFileChkLoop
		end
		if sPath == "DC260_02/RESERIES/"
			goto OutFileChkLoop
		end
	end
	if uCameraType == 265
		if sPath == "DC265_01/RESERIES/"
			goto OutFileChkLoop
		end
		if sPath == "DC265_02/RESERIES/"
			goto OutFileChkLoop
		end
	end
	if uCameraType == 290
		if sPath == "DC290_01/RESERIES/"
			goto OutFileChkLoop
		end
		if sPath == "DC290_02/RESERIES/"
			goto OutFileChkLoop
		end
	end
	# RESERIES path has not been found
	if uIndex == uCount - 1
		goto ContinueScript
	end
	uIndex = uIndex + 1
	goto FileChkLoop

# if files has been found
OutFileChkLoop:
	DisplayClear()
	DisplayLine("Found previously taken Resolution Series test pictures. ")
	Display("Please select from following options:")
	Wait(5000)
	
	# display a option list
	DisplayClear()
	SetOption(1, "Erase Previous Test Pictures", 0)
	SetOption(2, "Add to Previous Test Pictures", 0)
	SetOption(3, "Exit", 0)
	GetOption(uMenu)

	# erase all pictures in the RESERIES album
	if uMenu == 1
		DisplayClear()
		DisplayLine("")
		DisplayLine("Please wait...")
		uIndex = uCount - 1
FileEraseLoop:
		GetFileInfo(uIndex, sPath, nName, uLength, bStatus)
		if uCameraType == 220
			if sPath == "DC220_01/RESERIES/"
				EraseFile(sPath, nName);
			end
			if sPath == "DC220_02/RESERIES/"
				EraseFile(sPath, nName);
			end
		end
		if uCameraType == 260
			if sPath == "DC260_01/RESERIES/"
				EraseFile(sPath, nName)
			end
			if sPath == "DC260_02/RESERIES/"
				EraseFile(sPath, nName)
			end
		end
		if uCameraType == 265
			if sPath == "DC265_01/RESERIES/"
				EraseFile(sPath, nName)
			end
			if sPath == "DC265_02/RESERIES/"
				EraseFile(sPath, nName)
			end
		end
		if uCameraType == 290
			if sPath == "DC290_01/RESERIES/"
				EraseFile(sPath, nName)
			end
			if sPath == "DC290_02/RESERIES/"
				EraseFile(sPath, nName)
			end
		end
		if uIndex == 0
			goto ContinueScript
		end
		uIndex = uIndex - 1
		goto FileEraseLoop
	end

	# continue taking pictures into RESERIES album
	if uMenu == 2
		goto ContinueScript
	end

	# quit script
	if uMenu == 3
		goto Done
	end


ContinueScript:

# Get current camera states

# watermark enalbe
GetCameraState ("wena", uWena)
# background color
GetCameraState ("wsbc", uWsbc)
# string color
GetCameraState ("wsfc", uWsfc)
# graphic operation
GetCameraState ("wsop", uWsop)
# position - x
GetCameraState ("wsxp", uWsxp)
# position - y
GetCameraState ("wsyp", uWsyp)
# watermark text
GetCameraState ("wstr", sWstr)
# AC timeout
GetCameraState ("actc", uActc)
# battery timeout
GetCameraState ("bttc", uBttc)

DisplayClear()
if uCameraType == 220
	DisplayLine("6 Pictures will be taken in about 2 minutes.")
end
if uCameraType == 260
	DisplayLine("9 pictures will be taken in about 4 minutes.")
end
if uCameraType == 265
	DisplayLine("12 pictures will be taken in about 5 minutes.")
end
if uCameraType == 290
	DisplayLine("15 pictures will be taken in about 8 minutes.")
end
DisplayLine("Point the camera to an object with fine details.")
Wait (5000)

DisplayClear()
# DisplayLine("")
DisplayLine("Place your camera on a stable surface.")
DisplayLine("Do not move the camera during shooting.")
Wait (5000)

# use Alert to display a screen - it is not an alert
Alert ("Press 'Continue' When Ready")

# set camera states

# enable watermark
SetCameraState ("wena", 4)
# black background
SetCameraState ("wsbc", 63)
# white text
SetCameraState ("wsfc", 0)
SetCameraState ("wsop", 0)
SetCameraState ("wsxp", 0)
SetCameraState ("wsyp", 0)

DisplayClear()

# in case of DC220 camera
# go through all resoluton/quality combinations
if uCameraType == 220
	# make sure all pictures are taken before timeout
        SetCameraState ("actc", 240)
	SetCameraState ("bttc", 240)
	
	DisplayLine("First Picture (6 remain):")
	DisplayLine("")
	DisplayLine("High Resolution (1152X864)")
	DisplayLine("Best Quality")
	Wait (3000)

Picture22010:
	# set resolution and quality
	SetCameraState ("ssiz", 1)
	SetCameraState ("scpn", 4)
	# set watermark text
	SetCameraState ("wstr", " High Res with Best Quality ")
	# take picture
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")
	# display count down meter
	DisplayLine("")
	Display("10")
	Wait (950)
	iCount = 10
Loop22010:        
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop22010
	end
	
	DisplayClear()
	DisplayLine("Next Picture (5 remain):")
	DisplayLine("")
	DisplayLine("High Resolution (1152X864)")
	DisplayLine("Better Quality")
	Wait (3000)

Picture22011:
	SetCameraState ("scpn", 3)
	SetCameraState ("wstr", " High Res with Better Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")

	DisplayLine("")
	Display("10")
	Wait (950)
	iCount = 10
Loop22011:        
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop22011
	end
	
	DisplayClear()
	DisplayLine("Next Picture (4 remain):")
	DisplayLine("")
	DisplayLine("High Resolution (1152X864)")
	DisplayLine("Good Quality")
	Wait (3000)

Picture22012:
	SetCameraState ("scpn", 2)
	SetCameraState ("wstr", " High Res with Good Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")

	DisplayLine("")
	Display("10")
	Wait (950)
	iCount = 10
Loop22012:        
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop22012
	end
	
	DisplayClear()
	DisplayLine("Next Picture (3 remain):")
	DisplayLine("")
	DisplayLine("Standard Resolution (640X480)")
	DisplayLine("Best Quality")
	Wait (3000)

Picture22020:
	SetCameraState ("ssiz", 3)
	SetCameraState ("scpn", 4)
	SetCameraState ("wstr", " Standard Res/Best Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")

	DisplayLine("")
	Display("5")
	Wait (950)
	iCount = 5
Loop22020:        
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop22020
	end
	
	DisplayClear()
	DisplayLine("Next Picture (2 remain):")
	DisplayLine("")
	DisplayLine("Standard Resolution (640X480)")
	DisplayLine("Better Quality")
	Wait (3000)

Picture22021:
	SetCameraState ("scpn", 3)
	SetCameraState ("wstr", " Standard Res/Better Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")

	DisplayLine("")
	Display("5")
	Wait (950)
	iCount = 5
Loop22021:        
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop22021
	end
	
	DisplayClear()
	DisplayLine("Last Picture:")
	DisplayLine("")
	DisplayLine("Standard Resolution (640X480)")
	DisplayLine("Good Quality")
	Wait (3000)

Picture22022:
	SetCameraState ("scpn", 2)
	SetCameraState ("wstr", " Standard Res/Good Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
end

# in case of DC260 camera
# go through all resoluton/quality combinations
if uCameraType == 260
	# make sure all pictures are taken before timeout
	SetCameraState ("actc", 360)
	SetCameraState ("bttc", 360)
	DisplayLine("First Picture (9 remain):")
	DisplayLine("")
	DisplayLine("High Resolution (1536X1024)")
	DisplayLine("Best Quality")
	Wait (3000)

Picture26010:
	# set resolution and quality
	SetCameraState ("ssiz", 1)
	SetCameraState ("scpn", 4)
	# set watermark
	SetCameraState ("wstr", " High Res/Best Quality ")
	# take picture
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")
	# display count down meter
	DisplayLine("")
	Display("20")
	Wait (950)
	iCount = 19
Loop26010:        
	if iCount == 10
		DisplayLine("")
		Display("10")
		Wait (950)
	end
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop26010
	end
	
	DisplayClear()
	DisplayLine("Next Picture (8 remain):")
	DisplayLine("")    
	DisplayLine("High Resolution (1536X1024)")
	DisplayLine("Better Quality")
	Wait(3000)

Picture26011:
	SetCameraState ("scpn", 3)
	SetCameraState ("wstr", " High Res/Better Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")

	DisplayLine("")
	Display("20")
	Wait (950)
	iCount = 19
Loop26011:        
	if iCount == 10
		DisplayLine("")
		Display("10")
		Wait (950)
	end
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop26011
	end
	
	DisplayClear()
	DisplayLine("Next Picture (7 remain):")
	DisplayLine("")
	DisplayLine("High Resolution (1536X1024)")
	DisplayLine("Good Quality")
	Wait (3000)

Picture26012:
	SetCameraState ("scpn", 2)
	SetCameraState ("wstr", " High Res/Good Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")

	DisplayLine("")
	Display("20")
	Wait (950)
	iCount = 19
Loop26012:        
	if iCount == 10
		DisplayLine("")
		Display("10")
		Wait (950)
	end
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop26012
	end
	
	DisplayClear()
	DisplayLine("Next Picture (6 remain):")
	DisplayLine("")
	DisplayLine("Medium Resolution (1152X768)")
	DisplayLine("Best Quality")
	Wait (3000)

Picture26020:
	SetCameraState ("ssiz", 2)
	SetCameraState ("scpn", 4)
	SetCameraState ("wstr", " Medium Res/Best Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")

	DisplayLine("")
	Display("15")
	Wait (950)
	iCount = 14
Loop26020:        
	if iCount == 10
		DisplayLine("")
		Display("10")
		Wait (950)
	end
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop26020
	end
	
	DisplayClear()
	DisplayLine("Next Picture (5 remain):")
	DisplayLine("")
	DisplayLine("Medium Resolution (1152X768)")
	DisplayLine("Better Quality")
	Wait (3000)

Picture26021:
	SetCameraState ("scpn", 3)
	SetCameraState ("wstr", " Medium Res/Better Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")

	DisplayLine("")
	Display("15")
	Wait (950)
	iCount = 14
Loop26021:        
	if iCount == 10
		DisplayLine("")
		Display("10")
		Wait (950)
	end
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop26021
	end
	
	DisplayClear()
	DisplayLine("Next Picture (4 remain):")
	DisplayLine("")
	DisplayLine("Medium Resolution (1152X768)")
	DisplayLine("Good Quality")
	Wait (3000)

Picture26022:
	SetCameraState ("scpn", 2)
	SetCameraState ("wstr", " Medium Res/Good Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")

	DisplayLine("")
	Display("15")
	Wait (950)
	iCount = 14
Loop26022:        
	if iCount == 10
		DisplayLine("")
		Display("10")
		Wait (950)
	end
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop26022
	end
	
	DisplayClear()
	DisplayLine("Next Picture (3 remain):")
	DisplayLine("")
	DisplayLine("Standard Resolution (768X512)")
	DisplayLine("Best Quality")
	Wait (3000)

Picture26030:
	SetCameraState ("ssiz", 3)
	SetCameraState ("scpn", 4)
	SetCameraState ("wstr", " Standard Res/Best Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")
	
	DisplayLine("")
	Display("10")
	Wait (950)
	iCount = 10
Loop26030:        
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop26030
	end
	
	DisplayClear()
	DisplayLine("Next Picture (2 remain):")
	DisplayLine("")
	DisplayLine("Standard Resolution (768X512)")
	DisplayLine("Better Quality")
	Wait (3000)

Picture26031:
	SetCameraState ("scpn", 3)
	SetCameraState ("wstr", " Standard Res/Better Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
	DisplayClear()
	DisplayLine("Please Wait...")

	DisplayLine("")
	Display("10")
	Wait (950)
	iCount = 10
Loop26031:        
	Display(" .")
	Wait (950)
	iCount = iCount - 1
	if iCount != 1
		goto Loop26031
	end
	
	DisplayClear()
	DisplayLine("Last Picture:")
	DisplayLine("")
	DisplayLine("Standard Resolution (768X512)")
	DisplayLine("Good Quality")
	Wait (3000)

Picture26032:
	SetCameraState ("scpn", 2)
	SetCameraState ("wstr", " Standard Res/Good Quality ")
	StartCapture (sGName, 1, 1)
	Wait(5000)
end

# in case of DC265 camera
# go through all resoluton/quality combinations
if uCameraType == 265
	# make sure all pictures are taken before timeout
	SetCameraState ("actc", 360)
	SetCameraState ("bttc", 360)
	iMcount = 12
GetNextPic:
	if iMcount == 12
		DisplayLine("First Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("High Resolution (1536X1024)")
		DisplayLine("Super Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 1)
		SetCameraState ("scpn", 5)
		# set watermark
		SetCameraState ("wstr", " High Res/Super Quality ")
	end	
	if iMcount == 11
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("High Resolution (1536X1024)")
		DisplayLine("Best Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 1)
		SetCameraState ("scpn", 4)
		# set watermark
		SetCameraState ("wstr", " High Res/Best Quality ")
	end	
	if iMcount == 10
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("High Resolution (1536X1024)")
		DisplayLine("Better Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 1)
		SetCameraState ("scpn", 3)
		# set watermark
		SetCameraState ("wstr", " High Res/Better Quality ")
	end	
	if iMcount == 9
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("High Resolution (1536X1024)")
		DisplayLine("Good Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 1)
		SetCameraState ("scpn", 2)
		# set watermark
		SetCameraState ("wstr", " High Res/Good Quality ")
	end	
	if iMcount == 8
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("Medium Resolution (1152X768)")
		DisplayLine("Super Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 2)
		SetCameraState ("scpn", 5)
		# set watermark
		SetCameraState ("wstr", " Medium Res/Super Quality ")
	end	
	if iMcount == 7
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("Medium Resolution (1152X768)")
		DisplayLine("Best Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 2)
		SetCameraState ("scpn", 4)
		# set watermark
		SetCameraState ("wstr", " Medium Res/Best Quality ")
	end	
	if iMcount == 6
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("Medium Resolution (1152X768)")
		DisplayLine("Better Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 2)
		SetCameraState ("scpn", 3)
		# set watermark
		SetCameraState ("wstr", " Medium Res/Better Quality ")
	end	
	if iMcount == 5
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("Medium Resolution (1152X768)")
		DisplayLine("Good Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 2)
		SetCameraState ("scpn", 2)
		# set watermark
		SetCameraState ("wstr", " Medium Res/Good Quality ")
	end	
	if iMcount == 4
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("Standard Resolution (768X512)")
		DisplayLine("Super Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 3)
		SetCameraState ("scpn", 5)
		# set watermark
		SetCameraState ("wstr", " Standard Res/Super Quality ")
	end	
	if iMcount == 3
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("Standard Resolution (768X512)")
		DisplayLine("Best Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 3)
		SetCameraState ("scpn", 4)
		# set watermark
		SetCameraState ("wstr", " Standard Res/Best Quality ")
	end	
	if iMcount == 2
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("Standard Resolution (768X512)")
		DisplayLine("Better Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 3)
		SetCameraState ("scpn", 3)
		# set watermark
		SetCameraState ("wstr", " Standard Res/Better Quality ")
	end	
	if iMcount == 1
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("Standard Resolution (768X512)")
		DisplayLine("Good Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 3)
		SetCameraState ("scpn", 2)
		# set watermark
		SetCameraState ("wstr", " Standard Res/Good Quality ")
	end	
	if iMcount < 1
		goto DC265_End
	end
Takepic:
	DisplayClear()
	uError = StartCapture (sGName, 1, 1)
	DisplayLine("")
	Display("Please wait")
Countdown:	
	GetCameraStatus(bsystat, bcamstat, bvendstat)
	if bsystat & bMask 
		Display(".")
		Wait (950)
		goto Countdown
	end
	iMcount=iMcount - 1
	DisplayClear()
	goto GetNextPic

DC265_End:

end

# in case of DC290 camera
# go through all resoluton/quality combinations
if uCameraType == 290
	# make sure all pictures are taken before timeout
	SetCameraState ("actc", 480)
	SetCameraState ("bttc", 480)
	iMcount = 15
GetNextDC290Pic:
	if iMcount == 15
		DisplayLine("First Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("Ultra Resolution (2240X1500)")
		DisplayLine("Best Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 4)
		SetCameraState ("scpn", 4)
		# set watermark
		SetCameraState ("wstr", " Ultra Res/Best Quality ")
	end	
	if iMcount == 14
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("Ultra Resolution (2240X1500)")
		DisplayLine("Better Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 4)
		SetCameraState ("scpn", 3)
		# set watermark
		SetCameraState ("wstr", " Ultra Res/Better Quality ")
	end	
	if iMcount == 13
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("Ultra Resolution (2240X1500)")
		DisplayLine("Good Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 4)
		SetCameraState ("scpn", 2)
		# set watermark
		SetCameraState ("wstr", " Ultra Res/Good Quality ")
	end	
	if iMcount == 12
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("High Resolution (1792X1200)")
		DisplayLine("Uncompressed Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 1)
		SetCameraState ("scpn", 7)
		# set watermark
		SetCameraState ("wstr", " High Res/Uncompressed Quality ")
	end	
	if iMcount == 11
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("High Resolution (1792X1200)")
		DisplayLine("Best Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 1)
		SetCameraState ("scpn", 4)
		# set watermark
		SetCameraState ("wstr", " High Res/Best Quality ")
	end	
	if iMcount == 10
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("High Resolution (1792X1200)")
		DisplayLine("Better Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 1)
		SetCameraState ("scpn", 3)
		# set watermark
		SetCameraState ("wstr", " High Res/Better Quality ")
	end	
	if iMcount == 9
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("High Resolution (1792X1200)")
		DisplayLine("Good Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 1)
		SetCameraState ("scpn", 2)
		# set watermark
		SetCameraState ("wstr", " High Res/Good Quality ")
	end	
	if iMcount == 8
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("Medium Resolution (1440X960)")
		DisplayLine("Uncompressed Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 2)
		SetCameraState ("scpn", 7)
		# set watermark
		SetCameraState ("wstr", " Medium Res/Uncompressed Quality ")
	end	
	if iMcount == 7
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("Medium Resolution (1440X960)")
		DisplayLine("Best Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 2)
		SetCameraState ("scpn", 4)
		# set watermark
		SetCameraState ("wstr", " Medium Res/Best Quality ")
	end	
	if iMcount == 6
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("Medium Resolution (1440X960)")
		DisplayLine("Better Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 2)
		SetCameraState ("scpn", 3)
		# set watermark
		SetCameraState ("wstr", " Medium Res/Better Quality ")
	end	
	if iMcount == 5
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("Medium Resolution (1440X960)")
		DisplayLine("Good Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 2)
		SetCameraState ("scpn", 2)
		# set watermark
		SetCameraState ("wstr", " Medium Res/Good Quality ")
	end	
	if iMcount == 4
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("Standard Resolution (720X480)")
		DisplayLine("Uncompressed Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 3)
		SetCameraState ("scpn", 7)
		# set watermark
		SetCameraState ("wstr", " Standard Res/Uncompressed Quality ")
	end	
	if iMcount == 3
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("Standard Resolution (720X480)")
		DisplayLine("Best Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 3)
		SetCameraState ("scpn", 4)
		# set watermark
		SetCameraState ("wstr", " Standard Res/Best Quality ")
	end	
	if iMcount == 2
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("   ")
		DisplayLine("Standard Resolution (720X480)")
		DisplayLine("Better Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 3)
		SetCameraState ("scpn", 3)
		# set watermark
		SetCameraState ("wstr", " Standard Res/Better Quality ")
	end	
	if iMcount == 1
		DisplayLine("Next Picture (",iMcount," remain):")
		DisplayLine("")
		DisplayLine("Standard Resolution (720X480)")
		DisplayLine("Good Quality")
		Wait (3000)
		# set resolution and quality
		SetCameraState ("ssiz", 3)
		SetCameraState ("scpn", 2)
		# set watermark
		SetCameraState ("wstr", " Standard Res/Good Quality ")
	end	
	if iMcount < 1
		goto DC290_End
	end
TakeDC290Pic:
	DisplayClear()
	uError = StartCapture (sGName, 1, 1)
	DisplayLine("   ")
	Display("Please wait")
CountdownDC290:	
	GetCameraStatus(bsystat, bcamstat, bvendstat)
	if bsystat & bMask 
		Display(".")
		Wait (950)
		goto CountdownDC290
	end
	iMcount=iMcount - 1
	DisplayClear()
	goto GetNextDC290Pic

DC290_End:

end

# end group capture
EndCapture(sGName)

DisplayClear()
DisplayLine("All pictures taken.")
DisplayLine("")
if uCameraType == 220
	Display("Please review the last 6 pictures to select ")
end
if uCameraType == 260
	Display("Please review the last 9 pictures to select ")
end
if uCameraType == 265
	Display("Please review the last 12 pictures to select ")
end
if uCameraType == 290
	Display("Please review the last 15 pictures to select ")
end

Display("a resolution/quality combination.")

# reset camera states
SetCameraState ("ssiz", uSsiz)
SetCameraState ("scpn", uScpn)
SetCameraState ("wena", uWena)
SetCameraState ("wsbc", uWsbc)
SetCameraState ("wsfc", uWsfc)
SetCameraState ("wsop", uWsop)
SetCameraState ("wsxp", uWsxp)
SetCameraState ("wsyp", uWsyp)
SetCameraState ("wstr", sWstr)
SetCameraState ("actc", uActc)
SetCameraState ("bttc", uBttc)

Wait (10000)

Done:

exitscript